DataBatrix » Code Snippets

.NET Serialization: Binary, SOAP, and XML (VB)

Eric — Thu, 08 Oct 2009 23:43:50 +0000

In .NET when you need to shrink an object into a more portable format you have 3 choices. Binary, SOAP, or XML. The process of shrinking and expanding the object is called serialization and deserialization. Each option has it’s own advantages which I will explain.

Binary

You can serialize an object into binary format quite easily using the .NET Framework. This is the quickest and smallest way to serialize; however, the binary format can only be deserialized using the same .NET Framework. This may be a problem for interoperability. It must be noted that this format will serialize Public and Private members (unlike XML serialization).

The example below shows how to serialize an object called “newCustomer”:

        Dim newCustomer As Contact = GetSampleContact()

        Using fs As New IO.FileStream(filePathandName & ".bin", IO.FileMode.Create)
            Dim binFormatter As New Runtime.Serialization.Formatters.Binary.BinaryFormatter()
            binFormatter.Serialize(fs, newCustomer)
        End Using

And here is the reverse to deserialize:

        Dim readCustomer As Contact

        Using fs As New IO.FileStream(filePathandName & ".bin", IO.FileMode.Open, IO.FileAccess.Read)
            Dim binFormatter As New Runtime.Serialization.Formatters.Binary.BinaryFormatter()
            readCustomer = CType(binFormatter.Deserialize(fs), Contact)
        End Using

SOAP

SOAP is another method. This is similar to the binary method except the serialized data is stored in a standardized form (SOAP) which will easily allow interoperability. Public and Private members are serialized using this method as well.
To serialize:

        Dim newCustomer As Contact = GetSampleContact()
        Using fs As New IO.FileStream(filePathandName & "SOAP.xml", IO.FileMode.Create)
            Dim soapFormattter As New Runtime.Serialization.Formatters.Soap.SoapFormatter()
            soapFormattter.Serialize(fs, newCustomer)
        End Using

And to deserialize:

        Dim readCustomer As Contact
        Using fs As New IO.FileStream(filePathandName & "SOAP.xml", IO.FileMode.Open, IO.FileAccess.Read)
            Dim soapFormattter As New Runtime.Serialization.Formatters.Soap.SoapFormatter()
            readCustomer = CType(soapFormattter.Deserialize(fs), Contact)
        End Using

XML

A third choice is using the XMLSerializer class. This method will only serialize Public properties and members and the object must be marked with the Serializable attribute and contain an empty constructor. This method of serialization will be smaller in size than the SOAP method since less information is serialized. Here is an example of such class:

      Class Contact

        Private _FirstName As String
        Public Property FirstName() As String
            Get
                Return _FirstName
            End Get
            Set(ByVal value As String)
                _FirstName = value
            End Set
        End Property

        Private _LastName As String
        Public Property LastName() As String
            Get
                Return _LastName
            End Get
            Set(ByVal value As String)
                _LastName = value
            End Set
        End Property

        Private _MiddleI As String
        Public Property MiddleI() As String
            Get
                Return _MiddleI
            End Get
            Set(ByVal value As String)
                _MiddleI = value
            End Set
        End Property

        Private _PIN As String
        Public WriteOnly Property PIN() As String
            Set(ByVal value As String)
                _PIN = value
            End Set
        End Property

        Sub New()

        End Sub

        Sub New(ByVal fName As String, ByVal middleI As String, ByVal lName As String, ByVal p As String)
            _FirstName = fName
            _MiddleI = middleI
            _LastName = lName
            _PIN = p
        End Sub
    End Class

Here is how you would serialize using the XMLSerializer:

        Dim newCustomer As Contact = GetSampleContact()
        Using fs As New IO.FileStream(filePathandName & ".xml", IO.FileMode.Create)
            Dim xmlFormatter As New Xml.Serialization.XmlSerializer(GetType(Contact))
            xmlFormatter.Serialize(fs, newCustomer)
        End Using

And to deserialize:

        Dim readCustomer As Contact
        Using fs As New IO.FileStream(filePathandName & ".xml", IO.FileMode.Open, IO.FileAccess.Read)
            Dim xmlFormatter As New Xml.Serialization.XmlSerializer(GetType(Contact))
            readCustomer = CType(xmlFormatter.Deserialize(fs), Contact)
        End Using

You can download a sample serialization demo project that I created to demonstrate: SerializationDemoProject.zip.

Cross-thread operation not valid: .NET Cross Threading To Update Form Control

Eric — Thu, 03 Sep 2009 13:18:45 +0000

Cross-thread operation not valid

So you get the “Cross-thread operation not valid” error because you are trying to update an object on your form from a thread. I am not going to try to “glamor” you (True Blood reference) with fundamentals of delegates, threading, etc. If that is what you are looking for, search Google and you will find tons of references that are overly complicated using all of the proper terminology that typically makes my head hurt. I WILL show you the few bits of code in Visual Basic that are needed to get around the error. Or perhaps you just need to update a form control from a background process so the application does not hang.

In the example below, I am needing to update a ListBox control from a separate thread. I need 2 items: a method to update the ListBox which takes a string as a parameter and a Delegate with a matching parameter signature.

Here is the Delegate:

Private Delegate Sub UpdateListboxDelegate(ByVal s As String)

And here is the method that actually updates the ListBox:

Private Sub UpdateListbox(ByVal s As String)
   If Me.InvokeRequired Then
      Me.BeginInvoke(New UpdateListboxDelegate(AddressOf UpdateListbox), New Object() {s})
      Return
   End If
   ListBox1.Items.Add(s)
End Sub

Here would be a sample of the main sub that is slow to process:

Public Sub LongProcess()
   For i As Integer = 0 To 100
      System.Threading.Thread.Sleep(5000)
      UpdateListbox("Currently on count: " & i)
   Next
End Sub

Now to kick off the thread:

ListBox1.Items.Clear()
Dim thread As New Threading.Thread(AddressOf LongProcess)
thread.Start()

That’s it! The easiest solution without getting overly complicated.

…and in case you are looking for C# (it’s growing on me too):

        private delegate void UpdateListboxDelegate(string s);

        private void UpdateListbox(string s)
        {
            if (this.InvokeRequired)
            {
                this.BeginInvoke(new UpdateListboxDelegate(UpdateListbox), new object[] { s });
                return;
            }
            listBox1.Items.Add(s);
        }

        public void LongProcess()
        {
            for (int i = 0; i < 10; i++)
            {
                System.Threading.Thread.Sleep(1000);
                UpdateListbox("Currently on count: " + i.ToString());
            }
        }

        private void button2_Click(object sender, EventArgs e)
        {
            System.Threading.Thread thread = new System.Threading.Thread(LongProcess);
            thread.Start();
        }

A .NET Bit.ly API Helper Class (Visual Basic.NET)

Eric — Mon, 24 Aug 2009 21:19:19 +0000

I decided to write a helper class for using the Bit.ly API for creating short urls. You know, those tiny links that you see all over Facebook, Twitter, etc. The snippet below shows how you would use the helper class. Not only can you shorten an url, you can shorted multiple urls in a single call as well as get stats and info about a bit.ly url. If you are looking to incorporate bit.ly short urls in your application using their API access, this will save you some time. The class uses the XmlSerializer for reading bit.ly’s response.

        ' Pass username and API key to instantiate
        Dim newbitlyAPI As New DataBatrix.bitlyAPI.bitlyAPI("bitlyapidemo", "R_0da49e0a9118ff35f52f629d2d71bf07")

        ' Sample of creating 1 short URL
        Dim shortenResponse As DataBatrix.bitlyAPI.bitlyShortenResponse = newbitlyAPI.Shorten("http://www.databatrix.com")
        Dim shortURL As String = ""
        If shortenResponse.results.Count > 0 Then
            shortURL = shortenResponse.results(0).shortUrl
        End If

        ' Sample of creating multiple short URLs
        Dim longUrls() As String = {"http://www.databatrix.com", "http://www.google.com"}
        Dim shortenResponses As DataBatrix.bitlyAPI.bitlyShortenResponse = newbitlyAPI.Shorten(longUrls)
        Dim shortURLs(1) As String
        For i As Integer = 0 To shortenResponses.results.Count - 1
            shortURLs(i) = shortenResponses.results(i).shortUrl

        Next

        ' Sample of getting bit.ly info...
        Dim info As DataBatrix.bitlyAPI.bitlyInfoResponse = newbitlyAPI.Info("2bYgqR")

        ' Sample of getting bit.ly stats...
        Dim stats As DataBatrix.bitlyAPI.bitlyStatsResponse = newbitlyAPI.Stats("http://bit.ly/1RmnUT")

Below is the helper class that I created. You can download the VB file bitlyAPI.vb or a sample project TestBitly Project Files.

Imports System.Web
Imports System.Xml
Imports System.Xml.Serialization

Namespace DataBatrix.bitlyAPI
    Public Class bitlyAPI
        Const BaseAPIUrl As String = "http://api.bit.ly/"
        Const version As String = "2.0.1"
        Const format As String = "xml"

        Public login As String = String.Empty
        Public apiKey As String = String.Empty

        Sub New(ByVal login As String, ByVal apiKey As String)
            Me.login = login
            Me.apiKey = apiKey

        End Sub

        Private Function BuildBaseRequestURL(ByVal applicationName As String) As System.Text.StringBuilder
            Dim RequestUrl As New System.Text.StringBuilder()
            With RequestUrl
                .Append(BaseAPIUrl & HttpUtility.UrlEncode(applicationName) & "?")
                .Append("version=" & HttpUtility.UrlEncode(version) & "&")
                .Append("format=" & HttpUtility.UrlEncode(format) & "&")
                .Append("login=" & HttpUtility.UrlEncode(login) & "&")
                .Append("apiKey=" & HttpUtility.UrlEncode(apiKey) & "&")
            End With
            Return RequestUrl
        End Function

        Public Function Shorten(ByVal longUrl As String) As bitlyShortenResponse
            Dim logUrls() As String = {longUrl}
            Return Shorten(logUrls)
        End Function

        Public Function Shorten(ByVal longUrl() As String) As bitlyShortenResponse
            Dim RequestUrl As System.Text.StringBuilder = BuildBaseRequestURL("shorten")
            For Each s As String In longUrl
                RequestUrl.Append("&longUrl=" & HttpUtility.UrlEncode(s))

            Next
            Dim responseObj As DataBatrix.bitlyAPI.bitlyShortenResponse = Nothing
            Try
                Dim serializer = New XmlSerializer(GetType(DataBatrix.bitlyAPI.bitlyShortenResponse))
                Using reader As XmlTextReader = New XmlTextReader(RequestUrl.ToString())
                    responseObj = CType(serializer.Deserialize(reader), DataBatrix.bitlyAPI.bitlyShortenResponse)
                End Using

            Catch ex As Exception

            End Try

            If responseObj.errorCode > 0 Then
                Throw New ApplicationException("Error from bit.ly: " & responseObj.errorMessage)
            End If
            Return responseObj
        End Function
        Public Function Info(ByVal hash As String) As bitlyInfoResponse
            Dim RequestUrl As System.Text.StringBuilder = BuildBaseRequestURL("info")
            With RequestUrl
                .Append("hash=" & HttpUtility.UrlEncode(hash))
            End With

            Dim responseObj As DataBatrix.bitlyAPI.bitlyInfoResponse = Nothing
            Try
                Dim serializer = New XmlSerializer(GetType(DataBatrix.bitlyAPI.bitlyInfoResponse))
                Using reader As XmlTextReader = New XmlTextReader(RequestUrl.ToString())
                    responseObj = CType(serializer.Deserialize(reader), DataBatrix.bitlyAPI.bitlyInfoResponse)
                End Using

            Catch ex As Exception
                Throw New ApplicationException("API Error: " & ex.Message)
            End Try
            If responseObj.errorCode > 0 Then
                Throw New ApplicationException("Error from bit.ly: " & responseObj.errorMessage)
            End If
            Return responseObj
        End Function

        Public Function Stats(ByVal shortUrl As String) As bitlyStatsResponse
            Dim RequestUrl As System.Text.StringBuilder = BuildBaseRequestURL("stats")
            With RequestUrl
                .Append("shortUrl=" & HttpUtility.UrlEncode(shortUrl))

            End With

            Dim responseObj As DataBatrix.bitlyAPI.bitlyStatsResponse = Nothing
            Try
                Dim serializer = New XmlSerializer(GetType(DataBatrix.bitlyAPI.bitlyStatsResponse))
                Using reader As XmlTextReader = New XmlTextReader(RequestUrl.ToString())
                    responseObj = CType(serializer.Deserialize(reader), DataBatrix.bitlyAPI.bitlyStatsResponse)
                End Using

            Catch ex As Exception
                Throw New ApplicationException("API Error: " & ex.Message)
            End Try
            If responseObj.errorCode > 0 Then
                Throw New ApplicationException("Error from bit.ly: " & responseObj.errorMessage)
            End If
            Return responseObj
        End Function

    End Class

    Public MustInherit Class bitlyResponseBase
         _
        Public errorCode As Integer = 0

         _
        Public errorMessage As String = String.Empty

         _
        Public statusCode As String = String.Empty

    End Class

     _
    Public Class bitlyShortenResponse
        Inherits bitlyResponseBase

         _
        Public results As New List(Of KeyVal)

        Public Class KeyVal
             _
             Public userHash As String

             _
             Public shortKeywordUrl As String

             _
             Public hash As String

             _
             Public longUrl As String

             _
             Public shortUrl As String

        End Class
    End Class

     _
    Public Class bitlyInfoResponse
        Inherits bitlyResponseBase

         _
        Public results As New List(Of bitlyInfoResultItem)

        Public Class bitlyInfoResultItem
             _
            Public shortenedByUser As String
             _
            Public keywords As String
             _
            Public hash As String
             _
            Public exif As String
             _
            Public surbl As String
             _
            Public contentLength As String
             _
            Public id3 As String
             _
            Public calais As String
             _
            Public longUrl As String
             _
            Public version As String
             _
            Public htmlMetaDescription As String
             _
            Public htmlMetaKeywords As String
             _
            Public calaisId As String
             _
            Public thumbnail As thumbnailObj
             _
            Public contentType As String
             _
            Public users As List(Of String)
             _
            Public globalHash As String
             _
            Public htmlTitle As String
             _
            Public metacarta As String
             _
            Public mirrorUrl As String
             _
            Public keyword As String
             _
            Public calaisResolutions As String
             _
            Public userHash As String

            Public Class thumbnailObj
                 _
                Public large As String
                 _
                Public small As String
                 _
                Public medium As String
            End Class

        End Class
    End Class

     _
Public Class bitlyStatsResponse
        Inherits bitlyResponseBase

         _
        Public hash As String
         _
        Public clicks As String

        Public Class bitlyStatsResultItem
             _
            Public None As String
             _
            Public direct As String
             _
            Public nodeKeyValue As List(Of KeyValue)
             _
            Public nodeKey As String

            Public Class KeyValue
                 _
            Public nodeValue As String
                 _
                Public nodeKey As String
            End Class
        End Class
    End Class

End Namespace

Custom Replace with Regular Expressions in .NET

Eric — Thu, 20 Aug 2009 19:05:34 +0000

This is the second time I have had to do something like this. So this time I am posting it for my reference. Regular expressions are amazing and amazingly difficult to understand sometimes, but they come in very handy. I was in a situation where I was going to need to feed in a custom template to be used similar to a “mail merge” situation. I would query a database, then for each record I would fill out an email using an email template. I decided to go with <:FieldName:> as the nomenclature of how a field would be inserted. For example, here are the query results:

FirstName	LastName	Company
Eric	Bridges	DataBatrix

My email template may look something like this:

Dear <:FirstName:> <:LastName:>,

You work for <:Company:>!

For the purpose of my project, I did not know what fields were going to be returned or what the email template looked like. I needed a simple way to replace all of the field placeholders with actual data. Regular expressions to the rescue! You can use a delegate to run your own replace function. I called my method MatchHandler which is passed a Match variable (the match that is found). In my example below, I replaced it with the corresponding item from _reader (my sqldatareader row).

    Private Function MatchHandler(ByVal m As Match) As String
        Dim fieldName As String = m.Groups("fieldName").ToString()
        If HasField(fieldName) Then
            Return _reader(fieldName)
        Else
            Return m.ToString()
        End If
    End Function

Next we have to create our delegate. Delegates are basically pointers for methods (functions/subs). I called my delegate “MatchDelegate” and pass it the address of my function I created above.

    Dim MatchDelegate As New MatchEvaluator(AddressOf MatchHandler)

Now to make it work! Define your regular expression pattern and instantiate a new RegularExpression object. Use the Replace method and pass the string to search and the delegate that we created.

    Private Function MergeFields(ByVal body As String) As String
        Dim returnValue As String = ""
        Dim pattern As String = "<:(?(.+?)):>"
        Dim regex As New Text.RegularExpressions.Regex(pattern)
        returnValue = regex.Replace(body, MatchDelegate)
        Return returnValue
    End Function

That’s it! Now you can do whatever you like when a match is found in your Replace method.

In case you were wondering what “(?(.+?))” in the pattern was all about, check out this link talking about regular expression groups.