The idea is that I have a custom object that I need to spin through to populate a TreeView. I created a couple of simple methods to do such. I though about using Reflection, but my method starting getting larger and larger because I was having to put in special code to handle certain Types (i.e. String, ICollection, etc). Since my typical Use Case was to spit out the results of a complex object returned from a ASMX or WCF service, I decided to go the Serialize route. My DTO class was typically already decorated with the [Serializable] attribute, if not, it was simple enought to add.

So first we serialize the object into a string of XML, then stuff that into a XmlDocument. Then you can loop through the elements while creating each TreeViewNode. That’s it!

        public void PopulateTreeView(object obj, TreeView tv)
        {
            System.Xml.Serialization.XmlSerializer serializer = new System.Xml.Serialization.XmlSerializer(obj.GetType());
            System.Text.StringBuilder sb = new System.Text.StringBuilder();  // StringBuilder to hold the XML
            using (System.Xml.XmlWriter writer = System.Xml.XmlWriter.Create(sb))
            {
                serializer.Serialize(writer, obj); // Serialize the object to XML
                System.Xml.XmlDocument xDoc = new System.Xml.XmlDocument();
                xDoc.LoadXml(sb.ToString());  // Shove it in a XmlDocument
                tv.Nodes.Add(PopulateNode(xDoc));  // Add the Nodes to the TreeView
            }
        }

        public TreeNode PopulateNode(System.Xml.XmlNode node)
        {
            TreeNode treenode = new TreeNode(node.Name);  // Add the Name to the Node
            if (node.ChildNodes.Count == 1) //Prevents ParentNode from displaying all of the InnerText
                treenode.Text += "=" + node.InnerText; // If only 1 ChildNode then add the InnerText

            for (int i = 0; i < node.ChildNodes.Count; i++)
            {
                if (node.ChildNodes[i].HasChildNodes)
                {
                    treenode.ChildNodes.Add(PopulateNode(node.ChildNodes[i]));
                }
            }
            return treenode;
        }

Then call the method to populate where “customObject” is the object you want displayed in your TreeView:

            PopulateTreeView(customObject, TreeView1);

I created a method that cycles through all of the controls and checks to see if it has the attribute “Required”, and if so, then add the RequiredFieldValidator and Ajax callout controls automatically. You could obviously expand on this to meet your specific needs.
Here is how you would markup your TextBox control:
<asp:TextBox Required=”true” ValidationGroup=”valGroup” ID=”TextBox1″ runat=”server” />

Here is the method in the code behind:

private void AddRequiredValidations(ControlCollection controls)
{
    List requiredValidators = new List();
    for (int i = 0; i < controls.Count; i++)
    {
        if (controls[i] is TextBox)
        {
            TextBox tb = (TextBox)controls[i];
            if (tb.Attributes["Required"] != null && Convert.ToBoolean(tb.Attributes["Required"]))
            {
                RequiredFieldValidator requiredValidator = new RequiredFieldValidator();
                requiredValidator.ErrorMessage = "Required";
                requiredValidator.ID = "required" + tb.ID;
                requiredValidator.Display = ValidatorDisplay.None;
                requiredValidator.ValidationGroup = tb.ValidationGroup;
                requiredValidator.ControlToValidate = tb.ID;
                // Add the RequiredFieldValidator to a list to be added later
                // Since we can't add them to the control as we are cycling through them
                requiredValidators.Add(requiredValidator); 

                tb.CausesValidation = true;
            }
        }

        if (controls[i].HasControls()) // If this control has child controls
        {
            AddRequiredValidations(controls[i].Controls); // Search the child controls too
        }
    }

    // Now we can actually add the RequiredFieldValidators since we are done cycling through the existing controls
    for (int i = 0; i < requiredValidators.Count; i++)
    {

        AjaxControlToolkit.ValidatorCalloutExtender callout = new AjaxControlToolkit.ValidatorCalloutExtender();
        callout.TargetControlID = requiredValidators[i].ID;
        callout.ID = requiredValidators[i].ID + "Callout";
        controls.Add(requiredValidators[i]);
        controls.Add(callout);
    }
}

Then all you have to do is call it in your Page_Load() method:

AddRequiredValidations(this.Controls);

This will work not only for a singe TextBox control, but also for TextBox controls buried inside a GridView or Repeater!

<ajax:ListSearchExtender ID="lseAjaxDdlFilter" runat="server" TargetControlID="ddlFilter" IsSorted="true" PromptPosition="Top" />

When debugging the issue, I would find that it would save and get the correct scroll position from the cookie; however, when setting the scrollTop:

document.getElementById('myDiv').scrollTop = scrollPosition;

It would not set.  The DIV’s scrollTop would be 0 before and after the statement above even after verifying that scrollPosition had an actual value!

I will also mention that the grid did have a decent about of data.  Actually, enough to make the page size about 3.5 MBs by the time HTML was rendered…almost 1 MB taken up by ViewState alone!  Because of AJAX and the amount of data in the grid, there was a noticeable amount of lag when using the page…not a lot, but noticeable.

Work Around:

I started to wonder if the above javascript (which ran on window.onload) may be running too quickly…or rather, ran before IE could finish with the rest of the AJAX/javascript code on the page.  So I tried this line instead of the one above:

setTimeout(function() { document.getElementById('myDiv').scrollTop = scrollPosition; }, 250);

So basically, I wanted to wait 250 milliseconds before setting the scrollTop.  Much to my surprise, this worked!  By this point I was too exhausted to keep knocking down the delay to see how low it could go and still work.  I couldn’t really notice the 250 delay in setting the scroll position, so that is where I ended.

Your mileage may vary, but in case you have a similar issue…try a small delay when setting the scrollTop before attempting to re-engineer the whole page.

Binary

You can serialize an object into binary format quite easily using the .NET Framework.  This is the quickest and smallest way to serialize; however, the binary format can only be deserialized using the same .NET Framework.  This may be a problem for interoperability. It must be noted that this format will serialize Public and Private members (unlike XML serialization).

The example below shows how to serialize an object called “newCustomer”:

        Dim newCustomer As Contact = GetSampleContact()

        Using fs As New IO.FileStream(filePathandName & ".bin", IO.FileMode.Create)
            Dim binFormatter As New Runtime.Serialization.Formatters.Binary.BinaryFormatter()
            binFormatter.Serialize(fs, newCustomer)
        End Using

And here is the reverse to deserialize:

        Dim readCustomer As Contact

        Using fs As New IO.FileStream(filePathandName & ".bin", IO.FileMode.Open, IO.FileAccess.Read)
            Dim binFormatter As New Runtime.Serialization.Formatters.Binary.BinaryFormatter()
            readCustomer = CType(binFormatter.Deserialize(fs), Contact)
        End Using

SOAP

SOAP is another method. This is similar to the binary method except the serialized data is stored in a standardized form (SOAP) which will easily allow interoperability. Public and Private members are serialized using this method as well.
To serialize:

        Dim newCustomer As Contact = GetSampleContact()
        Using fs As New IO.FileStream(filePathandName & "SOAP.xml", IO.FileMode.Create)
            Dim soapFormattter As New Runtime.Serialization.Formatters.Soap.SoapFormatter()
            soapFormattter.Serialize(fs, newCustomer)
        End Using

And to deserialize:

        Dim readCustomer As Contact
        Using fs As New IO.FileStream(filePathandName & "SOAP.xml", IO.FileMode.Open, IO.FileAccess.Read)
            Dim soapFormattter As New Runtime.Serialization.Formatters.Soap.SoapFormatter()
            readCustomer = CType(soapFormattter.Deserialize(fs), Contact)
        End Using

XML

A third choice is using the XMLSerializer class. This method will only serialize Public properties and members and the object must be marked with the Serializable attribute and contain an empty constructor. This method of serialization will be smaller in size than the SOAP method since less information is serialized. Here is an example of such class:

     <Serializable()> Class Contact

        Private _FirstName As String
        Public Property FirstName() As String
            Get
                Return _FirstName
            End Get
            Set(ByVal value As String)
                _FirstName = value
            End Set
        End Property

        Private _LastName As String
        Public Property LastName() As String
            Get
                Return _LastName
            End Get
            Set(ByVal value As String)
                _LastName = value
            End Set
        End Property

        Private _MiddleI As String
        Public Property MiddleI() As String
            Get
                Return _MiddleI
            End Get
            Set(ByVal value As String)
                _MiddleI = value
            End Set
        End Property

        Private _PIN As String
        Public WriteOnly Property PIN() As String
            Set(ByVal value As String)
                _PIN = value
            End Set
        End Property

        Sub New()

        End Sub

        Sub New(ByVal fName As String, ByVal middleI As String, ByVal lName As String, ByVal p As String)
            _FirstName = fName
            _MiddleI = middleI
            _LastName = lName
            _PIN = p
        End Sub
    End Class

Here is how you would serialize using the XMLSerializer:

        Dim newCustomer As Contact = GetSampleContact()
        Using fs As New IO.FileStream(filePathandName & ".xml", IO.FileMode.Create)
            Dim xmlFormatter As New Xml.Serialization.XmlSerializer(GetType(Contact))
            xmlFormatter.Serialize(fs, newCustomer)
        End Using

And to deserialize:

        Dim readCustomer As Contact
        Using fs As New IO.FileStream(filePathandName & ".xml", IO.FileMode.Open, IO.FileAccess.Read)
            Dim xmlFormatter As New Xml.Serialization.XmlSerializer(GetType(Contact))
            readCustomer = CType(xmlFormatter.Deserialize(fs), Contact)
        End Using

You can download a sample serialization demo project that I created to demonstrate: SerializationDemoProject.zip.

The company needed to track time logged to particular jobs/projects.  The initial idea was to use a site like ClickTime.  However, for an employee to log time against a job, you would need to tell ClickTime all of your jobs (which would be tedious) or configure an integration app to automatically populate the available jobs/projects.

Solution

I created a web application that would allow employees to log time against jobs/projects.  It would search instantly against their project management software for a list of available jobs.  The type of work was categorized for reporting.  Since we would have the employee’s hours, it would be used for payroll.  I implemented an export feature for preparing the payroll information for ADP and EDH.  Work time for each project was then entered into the project management software to be calculated as job cost.  As a bonus, you could use the gathered data to calculate each employees “utilization”.

Landing page.	Enter time for a particular project/job.
Apply costs to each job.	Payroll export options.
Utilization

Cross-thread operation not valid

So you get the “Cross-thread operation not valid” error because you are trying to update an object on your form from a thread. I am not going to try to “glamor” you (True Blood reference) with fundamentals of delegates, threading, etc. If that is what you are looking for, search Google and you will find tons of references that are overly complicated using all of the proper terminology that typically makes my head hurt. I WILL show you the few bits of code in Visual Basic that are needed to get around the error. Or perhaps you just need to update a form control from a background process so the application does not hang.

In the example below, I am needing to update a ListBox control from a separate thread.  I need 2 items: a method to update the ListBox which takes a string as a parameter and a Delegate with a matching parameter signature.

Here is the Delegate:

Private Delegate Sub UpdateListboxDelegate(ByVal s As String)

And here is the method that actually updates the ListBox:

Private Sub UpdateListbox(ByVal s As String)
   If Me.InvokeRequired Then
      Me.BeginInvoke(New UpdateListboxDelegate(AddressOf UpdateListbox), New Object() {s})
      Return
   End If
   ListBox1.Items.Add(s)
End Sub

Here would be a sample of the main sub that is slow to process:

Public Sub LongProcess()
   For i As Integer = 0 To 100
      System.Threading.Thread.Sleep(5000)
      UpdateListbox("Currently on count: " & i)
   Next
End Sub

Now to kick off the thread:

ListBox1.Items.Clear()
Dim thread As New Threading.Thread(AddressOf LongProcess)
thread.Start()

That’s it!  The easiest solution without getting overly complicated.

…and in case you are looking for C# (it’s growing on me too):

        private delegate void UpdateListboxDelegate(string s);

        private void UpdateListbox(string s)
        {
            if (this.InvokeRequired)
            {
                this.BeginInvoke(new UpdateListboxDelegate(UpdateListbox), new object[] { s });
                return;
            }
            listBox1.Items.Add(s);
        }

        public void LongProcess()
        {
            for (int i = 0; i < 10; i++)
            {
                System.Threading.Thread.Sleep(1000);
                UpdateListbox("Currently on count: " + i.ToString());
            }
        }

        private void button2_Click(object sender, EventArgs e)
        {
            System.Threading.Thread thread = new System.Threading.Thread(LongProcess);
            thread.Start();
        }

Reminder emails were needed to be sent out to remind sales staff to follow up on projects.

Solution

I developed a simple command line executable that takes 1 parameter which is an XML file.  The contents of the XML file would look something like:

<?xml version="1.0" encoding="utf-8" ?>
<Settings>
	<ErrorEmail>
		<Email>email@gmail.com</Email>
	</ErrorEmail>
	<SummaryEmail>
		<Email>email@gmail.com</Email>
	</SummaryEmail>
	<Query>
		SELECT * FROM Projects
		WHERE Cancelled = 0 And Completed = 0 AND BookDate IS NULL
		AND FollowUpBy <= getdate()
	</Query>
	<SQLConnectionString>Server=SQLServer;Database=MainDatabase;Persist Security Info=True;Integrated Security=true</SQLConnectionString>
	<TemplateEmailFileName>EmailTemplate.txt</TemplateEmailFileName>
	<EmailSubject>Alert Email For Project#<:ProjectID:></EmailSubject>
	<EmailDomain>mycompany.com</EmailDomain>
	<ToAddressDatabaseField>Salesperson</ToAddressDatabaseField>
	<ToAddressFieldIsEmail>0</ToAddressFieldIsEmail>
	<SMTPSettings>
		<SMTPServer>smtp.gmail.com</SMTPServer>
		<EnableSSL>1</EnableSSL>
		<RequiresAuthentication>1</RequiresAuthentication>
		<Username>email@gmail.com</Username>
		<Password>*******</Password>
		<Port>587</Port>
		<FromAddress>email@gmail.com</FromAddress>
	</SMTPSettings>
	<LogFileDirectory>Daily</LogFileDirectory>
</Settings>

The command line executable would then run the query (<Query>) against the supplied database in the XML file.  For each row returned, the program will send out an email to the user.  Which user?  What email?  The recipients email address would need to be one of the fields returned from the query and noted in the XML file in the element <ToAddressDatabaseField>.  The template for the email body is supplied by the <TemplateEmailFileName> element.   To make the email custom, it is possible to insert fields returned from the database into the email template.  For example, lets say the query returned a field called “FirstName”.  In the email template text file, you could have:

Hello <:FirstName:>,

When the program ran, it would swap “<:FirstName:>” with the contents from the database.  This is similar to a mail merge for emails.  Since all of the values are configurable in the XML file, the usage possibilities are unlimited!  Let say you needed to run this once a week, no problem.  Set up a Windows Scheduled Task to run the executable at the specified interval.

        ' Pass username and API key to instantiate
        Dim newbitlyAPI As New DataBatrix.bitlyAPI.bitlyAPI("bitlyapidemo", "R_0da49e0a9118ff35f52f629d2d71bf07")

        ' Sample of creating 1 short URL
        Dim shortenResponse As DataBatrix.bitlyAPI.bitlyShortenResponse = newbitlyAPI.Shorten("http://www.databatrix.com")
        Dim shortURL As String = ""
        If shortenResponse.results.Count > 0 Then
            shortURL = shortenResponse.results(0).shortUrl
        End If

        ' Sample of creating multiple short URLs
        Dim longUrls() As String = {"http://www.databatrix.com", "http://www.google.com"}
        Dim shortenResponses As DataBatrix.bitlyAPI.bitlyShortenResponse = newbitlyAPI.Shorten(longUrls)
        Dim shortURLs(1) As String
        For i As Integer = 0 To shortenResponses.results.Count - 1
            shortURLs(i) = shortenResponses.results(i).shortUrl

        Next

        ' Sample of getting bit.ly info...
        Dim info As DataBatrix.bitlyAPI.bitlyInfoResponse = newbitlyAPI.Info("2bYgqR")

        ' Sample of getting bit.ly stats...
        Dim stats As DataBatrix.bitlyAPI.bitlyStatsResponse = newbitlyAPI.Stats("http://bit.ly/1RmnUT")

Below is the helper class that I created.  You can download the VB file bitlyAPI.vb or a sample project TestBitly Project Files.

Imports System.Web
Imports System.Xml
Imports System.Xml.Serialization

Namespace DataBatrix.bitlyAPI
    Public Class bitlyAPI
        Const BaseAPIUrl As String = "http://api.bit.ly/"
        Const version As String = "2.0.1"
        Const format As String = "xml"

        Public login As String = String.Empty
        Public apiKey As String = String.Empty

        Sub New(ByVal login As String, ByVal apiKey As String)
            Me.login = login
            Me.apiKey = apiKey

        End Sub

        Private Function BuildBaseRequestURL(ByVal applicationName As String) As System.Text.StringBuilder
            Dim RequestUrl As New System.Text.StringBuilder()
            With RequestUrl
                .Append(BaseAPIUrl & HttpUtility.UrlEncode(applicationName) & "?")
                .Append("version=" & HttpUtility.UrlEncode(version) & "&")
                .Append("format=" & HttpUtility.UrlEncode(format) & "&")
                .Append("login=" & HttpUtility.UrlEncode(login) & "&")
                .Append("apiKey=" & HttpUtility.UrlEncode(apiKey) & "&")
            End With
            Return RequestUrl
        End Function

        Public Function Shorten(ByVal longUrl As String) As bitlyShortenResponse
            Dim logUrls() As String = {longUrl}
            Return Shorten(logUrls)
        End Function

        Public Function Shorten(ByVal longUrl() As String) As bitlyShortenResponse
            Dim RequestUrl As System.Text.StringBuilder = BuildBaseRequestURL("shorten")
            For Each s As String In longUrl
                RequestUrl.Append("&longUrl=" & HttpUtility.UrlEncode(s))

            Next
            Dim responseObj As DataBatrix.bitlyAPI.bitlyShortenResponse = Nothing
            Try
                Dim serializer = New XmlSerializer(GetType(DataBatrix.bitlyAPI.bitlyShortenResponse))
                Using reader As XmlTextReader = New XmlTextReader(RequestUrl.ToString())
                    responseObj = CType(serializer.Deserialize(reader), DataBatrix.bitlyAPI.bitlyShortenResponse)
                End Using

            Catch ex As Exception

            End Try

            If responseObj.errorCode > 0 Then
                Throw New ApplicationException("Error from bit.ly: " & responseObj.errorMessage)
            End If
            Return responseObj
        End Function
        Public Function Info(ByVal hash As String) As bitlyInfoResponse
            Dim RequestUrl As System.Text.StringBuilder = BuildBaseRequestURL("info")
            With RequestUrl
                .Append("hash=" & HttpUtility.UrlEncode(hash))
            End With

            Dim responseObj As DataBatrix.bitlyAPI.bitlyInfoResponse = Nothing
            Try
                Dim serializer = New XmlSerializer(GetType(DataBatrix.bitlyAPI.bitlyInfoResponse))
                Using reader As XmlTextReader = New XmlTextReader(RequestUrl.ToString())
                    responseObj = CType(serializer.Deserialize(reader), DataBatrix.bitlyAPI.bitlyInfoResponse)
                End Using

            Catch ex As Exception
                Throw New ApplicationException("API Error: " & ex.Message)
            End Try
            If responseObj.errorCode > 0 Then
                Throw New ApplicationException("Error from bit.ly: " & responseObj.errorMessage)
            End If
            Return responseObj
        End Function

        Public Function Stats(ByVal shortUrl As String) As bitlyStatsResponse
            Dim RequestUrl As System.Text.StringBuilder = BuildBaseRequestURL("stats")
            With RequestUrl
                .Append("shortUrl=" & HttpUtility.UrlEncode(shortUrl))

            End With

            Dim responseObj As DataBatrix.bitlyAPI.bitlyStatsResponse = Nothing
            Try
                Dim serializer = New XmlSerializer(GetType(DataBatrix.bitlyAPI.bitlyStatsResponse))
                Using reader As XmlTextReader = New XmlTextReader(RequestUrl.ToString())
                    responseObj = CType(serializer.Deserialize(reader), DataBatrix.bitlyAPI.bitlyStatsResponse)
                End Using

            Catch ex As Exception
                Throw New ApplicationException("API Error: " & ex.Message)
            End Try
            If responseObj.errorCode > 0 Then
                Throw New ApplicationException("Error from bit.ly: " & responseObj.errorMessage)
            End If
            Return responseObj
        End Function

    End Class

    Public MustInherit Class bitlyResponseBase
        <Xml.Serialization.XmlElement("errorCode")> _
        Public errorCode As Integer = 0

        <Xml.Serialization.XmlElement("errorMessage")> _
        Public errorMessage As String = String.Empty

        <Xml.Serialization.XmlElement("statusCode")> _
        Public statusCode As String = String.Empty

    End Class

    <System.Serializable(), Xml.Serialization.XmlRoot("bitly")> _
    Public Class bitlyShortenResponse
        Inherits bitlyResponseBase

        <Xml.Serialization.XmlArray("results"), Xml.Serialization.XmlArrayItem("nodeKeyVal")> _
        Public results As New List(Of KeyVal)

        Public Class KeyVal
            <Xml.Serialization.XmlElement("userHash")> _
             Public userHash As String

            <Xml.Serialization.XmlElement("shortKeywordUrl")> _
             Public shortKeywordUrl As String

            <Xml.Serialization.XmlElement("hash")> _
             Public hash As String

            <Xml.Serialization.XmlElement("nodeKey")> _
             Public longUrl As String

            <Xml.Serialization.XmlElement("shortUrl")> _
             Public shortUrl As String

        End Class
    End Class

    <System.Serializable(), Xml.Serialization.XmlRoot("bitly")> _
    Public Class bitlyInfoResponse
        Inherits bitlyResponseBase

        <Xml.Serialization.XmlArray("results"), Xml.Serialization.XmlArrayItem("doc")> _
        Public results As New List(Of bitlyInfoResultItem)

        Public Class bitlyInfoResultItem
            <Xml.Serialization.XmlElement("shortenedByUser")> _
            Public shortenedByUser As String
            <Xml.Serialization.XmlElement("keywords")> _
            Public keywords As String
            <Xml.Serialization.XmlElement("hash")> _
            Public hash As String
            <Xml.Serialization.XmlElement("exif")> _
            Public exif As String
            <Xml.Serialization.XmlElement("surbl")> _
            Public surbl As String
            <Xml.Serialization.XmlElement("contentLength")> _
            Public contentLength As String
            <Xml.Serialization.XmlElement("id3")> _
            Public id3 As String
            <Xml.Serialization.XmlElement("calais")> _
            Public calais As String
            <Xml.Serialization.XmlElement("longUrl")> _
            Public longUrl As String
            <Xml.Serialization.XmlElement("version")> _
            Public version As String
            <Xml.Serialization.XmlElement("htmlMetaDescription")> _
            Public htmlMetaDescription As String
            <Xml.Serialization.XmlElement("htmlMetaKeywords")> _
            Public htmlMetaKeywords As String
            <Xml.Serialization.XmlElement("calaisId")> _
            Public calaisId As String
            <Xml.Serialization.XmlElement("thumbnail")> _
            Public thumbnail As thumbnailObj
            <Xml.Serialization.XmlElement("contentType")> _
            Public contentType As String
            <Xml.Serialization.XmlArray("users"), Xml.Serialization.XmlArrayItem("item")> _
            Public users As List(Of String)
            <Xml.Serialization.XmlElement("globalHash")> _
            Public globalHash As String
            <Xml.Serialization.XmlElement("htmlTitle")> _
            Public htmlTitle As String
            <Xml.Serialization.XmlElement("metacarta")> _
            Public metacarta As String
            <Xml.Serialization.XmlElement("mirrorUrl")> _
            Public mirrorUrl As String
            <Xml.Serialization.XmlElement("keyword")> _
            Public keyword As String
            <Xml.Serialization.XmlElement("calaisResolutions")> _
            Public calaisResolutions As String
            <Xml.Serialization.XmlElement("userHash")> _
            Public userHash As String

            Public Class thumbnailObj
                <Xml.Serialization.XmlElement("large")> _
                Public large As String
                <Xml.Serialization.XmlElement("small")> _
                Public small As String
                <Xml.Serialization.XmlElement("medium")> _
                Public medium As String
            End Class

        End Class
    End Class

    <System.Serializable(), Xml.Serialization.XmlRoot("bitly")> _
Public Class bitlyStatsResponse
        Inherits bitlyResponseBase

        <Xml.Serialization.XmlElement("hash")> _
        Public hash As String
        <Xml.Serialization.XmlElement("clicks")> _
        Public clicks As String

        Public Class bitlyStatsResultItem
            <Xml.Serialization.XmlElement("None")> _
            Public None As String
            <Xml.Serialization.XmlElement("direct")> _
            Public direct As String
            <Xml.Serialization.XmlArray("nodeKeyVal"), XmlArrayItem("nodeKeyVal")> _
            Public nodeKeyValue As List(Of KeyValue)
            <Xml.Serialization.XmlElement("nodeKey")> _
            Public nodeKey As String

            Public Class KeyValue
                <Xml.Serialization.XmlElement("nodeValue")> _
            Public nodeValue As String
                <Xml.Serialization.XmlElement("nodeKey")> _
                Public nodeKey As String
            End Class
        End Class
    End Class

End Namespace

My email template may look something like this:

Dear <:FirstName:> <:LastName:>,

You work for <:Company:>!

For the purpose of my project, I did not know what fields were going to be returned or what the email template looked like.  I needed a simple way to replace all of the field placeholders with actual data.  Regular expressions to the rescue!  You can use a delegate to run your own replace function.  I called my method MatchHandler which is passed a Match variable (the match that is found).  In my example below, I replaced it with the corresponding item from _reader (my sqldatareader row).

    Private Function MatchHandler(ByVal m As Match) As String
        Dim fieldName As String = m.Groups("fieldName").ToString()
        If HasField(fieldName) Then
            Return _reader(fieldName)
        Else
            Return m.ToString()
        End If
    End Function

Next we have to create our delegate.  Delegates are basically pointers for methods (functions/subs).  I called my delegate “MatchDelegate” and pass it the address of my function I created above.

    Dim MatchDelegate As New MatchEvaluator(AddressOf MatchHandler)

Now to make it work!  Define your regular expression pattern and instantiate a new RegularExpression object.  Use the Replace method and pass the string to search and the delegate that we created.

    Private Function MergeFields(ByVal body As String) As String
        Dim returnValue As String = ""
        Dim pattern As String = "<:(?<fieldName:>(.+?)):>"
        Dim regex As New Text.RegularExpressions.Regex(pattern)
        returnValue = regex.Replace(body, MatchDelegate)
        Return returnValue
    End Function

That’s it!  Now you can do whatever you like when a match is found in your Replace method.

In case you were wondering what “(?<fieldName:>(.+?))” in the pattern was all about, check out this link talking about regular expression groups.